附录 B. ABNF 的核心 ABNF

本附录包含一些常用的基本规则. 基本规则使用大写. 请注意, 这些规则仅对以 7 位 ASCII 编码、或以 7 位 ASCII 的超集字符集编码的 ABNF 有效.

B.1. 核心规则

某些基本规则使用大写, 例如 SP、HTAB、CRLF、DIGIT、ALPHA 等.

      ALPHA          =  %x41-5A / %x61-7A   ; A-Z / a-z

      BIT            =  "0" / "1"

      CHAR           =  %x01-7F
                             ; any 7-bit US-ASCII character,
                             ;  excluding NUL

      CR             =  %x0D
                             ; carriage return

      CRLF           =  CR LF
                             ; Internet standard newline

      CTL            =  %x00-1F / %x7F
                             ; controls

      DIGIT          =  %x30-39
                             ; 0-9

      DQUOTE         =  %x22
                             ; " (Double Quote)

      HEXDIG         =  DIGIT / "A" / "B" / "C" / "D" / "E" / "F"

      HTAB           =  %x09
                             ; horizontal tab

      LF             =  %x0A
                             ; linefeed

      LWSP           =  *(WSP / CRLF WSP)
                             ; Use of this linear-white-space rule
                             ;  permits lines containing only white
                             ;  space that are no longer legal in
                             ;  mail headers and have caused
                             ;  interoperability problems in other
                             ;  contexts.
                             ; Do not use when defining mail
                             ;  headers and use with caution in
                             ;  other contexts.

      OCTET          =  %x00-FF
                             ; 8 bits of data

      SP             =  %x20

      VCHAR          =  %x21-7E
                             ; visible (printing) characters

      WSP            =  SP / HTAB
                             ; white space

B.2. 常见编码

在外部, 数据表示为 "网络虚拟 ASCII" (即位于 8 位字段中的 7 位 US-ASCII), 其高位 (第 8 位) 置为零. 值字符串采用 "网络字节序", 其中数值较大的字节表示在左侧, 并首先通过网络发送.