Anhang B. Kern-ABNF von ABNF

Dieser Anhang enthält einige grundlegende Regeln, die allgemein gebräuchlich sind. Grundlegende Regeln werden in Großbuchstaben geschrieben. Beachten Sie, dass diese Regeln nur für ABNF gültig sind, das in 7-Bit-ASCII oder in Zeichensätzen kodiert ist, die eine Obermenge von 7-Bit-ASCII sind.

B.1. Kernregeln (Core Rules)

Bestimmte grundlegende Regeln werden in Großbuchstaben geschrieben, wie SP, HTAB, CRLF, DIGIT, ALPHA usw.

      ALPHA          =  %x41-5A / %x61-7A   ; A-Z / a-z

      BIT            =  "0" / "1"

      CHAR           =  %x01-7F
                             ; any 7-bit US-ASCII character,
                             ;  excluding NUL

      CR             =  %x0D
                             ; carriage return

      CRLF           =  CR LF
                             ; Internet standard newline

      CTL            =  %x00-1F / %x7F
                             ; controls

      DIGIT          =  %x30-39
                             ; 0-9

      DQUOTE         =  %x22
                             ; " (Double Quote)

      HEXDIG         =  DIGIT / "A" / "B" / "C" / "D" / "E" / "F"

      HTAB           =  %x09
                             ; horizontal tab

      LF             =  %x0A
                             ; linefeed

      LWSP           =  *(WSP / CRLF WSP)
                             ; Use of this linear-white-space rule
                             ;  permits lines containing only white
                             ;  space that are no longer legal in
                             ;  mail headers and have caused
                             ;  interoperability problems in other
                             ;  contexts.
                             ; Do not use when defining mail
                             ;  headers and use with caution in
                             ;  other contexts.

      OCTET          =  %x00-FF
                             ; 8 bits of data

      SP             =  %x20

      VCHAR          =  %x21-7E
                             ; visible (printing) characters

      WSP            =  SP / HTAB
                             ; white space

B.2. Gemeinsame Kodierung (Common Encoding)

Extern werden Daten als "network virtual ASCII" dargestellt (nämlich 7-Bit-US-ASCII in einem 8-Bit-Feld), wobei das hohe (8.) Bit auf null gesetzt ist. Eine Zeichenkette von Werten liegt in "network byte order" vor, wobei die Bytes mit höherem Wert auf der linken Seite dargestellt und zuerst über das Netzwerk gesendet werden.