Aller au contenu principal

Annexe B. ABNF de base de l'ABNF

Cette annexe contient quelques règles de base d'usage courant. Les règles de base sont en majuscules. Notez que ces règles ne sont valides que pour l'ABNF codé en ASCII 7 bits ou dans des jeux de caractères qui sont un sur-ensemble de l'ASCII 7 bits.

B.1. Règles de base​

Certaines règles de base sont en majuscules, telles que SP, HTAB, CRLF, DIGIT, ALPHA, etc.

      ALPHA          =  %x41-5A / %x61-7A   ; A-Z / a-z

      BIT            =  "0" / "1"

      CHAR           =  %x01-7F
                             ; any 7-bit US-ASCII character,
                             ;  excluding NUL

      CR             =  %x0D
                             ; carriage return

      CRLF           =  CR LF
                             ; Internet standard newline

      CTL            =  %x00-1F / %x7F
                             ; controls

      DIGIT          =  %x30-39
                             ; 0-9

      DQUOTE         =  %x22
                             ; " (Double Quote)

      HEXDIG         =  DIGIT / "A" / "B" / "C" / "D" / "E" / "F"

      HTAB           =  %x09
                             ; horizontal tab

      LF             =  %x0A
                             ; linefeed

      LWSP           =  *(WSP / CRLF WSP)
                             ; Use of this linear-white-space rule
                             ;  permits lines containing only white
                             ;  space that are no longer legal in
                             ;  mail headers and have caused
                             ;  interoperability problems in other
                             ;  contexts.
                             ; Do not use when defining mail
                             ;  headers and use with caution in
                             ;  other contexts.

      OCTET          =  %x00-FF
                             ; 8 bits of data

      SP             =  %x20

      VCHAR          =  %x21-7E
                             ; visible (printing) characters

      WSP            =  SP / HTAB
                             ; white space

B.2. Encodage courant​

Extérieurement, les données sont représentées en "network virtual ASCII" (à savoir de l'US-ASCII à 7 bits dans un champ de 8 bits), le bit de poids fort (8e) étant mis à zéro. Une chaîne de valeurs est en "network byte order", c'est-à-dire que les octets de valeur la plus élevée sont représentés du côté gauche et sont envoyés sur le réseau en premier.