Passa al contenuto principale

Appendice B. ABNF di base di ABNF

Questa appendice contiene alcune regole di base di uso comune. Le regole di base sono in maiuscolo. Si noti che queste regole sono valide solo per ABNF codificato in ASCII a 7 bit o in insiemi di caratteri che sono un sovrainsieme dell'ASCII a 7 bit.

B.1. Regole di base (Core Rules)​

Alcune regole di base sono in maiuscolo, come SP, HTAB, CRLF, DIGIT, ALPHA, ecc.

      ALPHA          =  %x41-5A / %x61-7A   ; A-Z / a-z

      BIT            =  "0" / "1"

      CHAR           =  %x01-7F
                             ; any 7-bit US-ASCII character,
                             ;  excluding NUL

      CR             =  %x0D
                             ; carriage return

      CRLF           =  CR LF
                             ; Internet standard newline

      CTL            =  %x00-1F / %x7F
                             ; controls

      DIGIT          =  %x30-39
                             ; 0-9

      DQUOTE         =  %x22
                             ; " (Double Quote)

      HEXDIG         =  DIGIT / "A" / "B" / "C" / "D" / "E" / "F"

      HTAB           =  %x09
                             ; horizontal tab

      LF             =  %x0A
                             ; linefeed

      LWSP           =  *(WSP / CRLF WSP)
                             ; Use of this linear-white-space rule
                             ;  permits lines containing only white
                             ;  space that are no longer legal in
                             ;  mail headers and have caused
                             ;  interoperability problems in other
                             ;  contexts.
                             ; Do not use when defining mail
                             ;  headers and use with caution in
                             ;  other contexts.

      OCTET          =  %x00-FF
                             ; 8 bits of data

      SP             =  %x20

      VCHAR          =  %x21-7E
                             ; visible (printing) characters

      WSP            =  SP / HTAB
                             ; white space

B.2. Codifica comune​

Esternamente, i dati sono rappresentati come "network virtual ASCII" (ossia US-ASCII a 7 bit in un campo a 8 bit), con il bit alto (l'ottavo) impostato a zero. Una stringa di valori è in "network byte order" (ordine dei byte di rete), in cui i byte di valore più alto sono rappresentati sul lato sinistro e vengono inviati sulla rete per primi.