Skip to main content

3. Operators

3.1. Concatenation: Rule1 Rule2​

A rule can define a simple, ordered string of values (i.e., a concatenation of contiguous characters) by listing a sequence of rule names. For example:

      foo         =  %x61           ; a

      bar         =  %x62           ; b

      mumble      =  foo bar foo

So that the rule matches the lowercase string "aba".

Linear white space: Concatenation is at the core of the ABNF parsing model. A string of contiguous characters (values) is parsed according to the rules defined in ABNF. For Internet specifications, there is some history of permitting linear white space (space and horizontal tab) to be freely and implicitly interspersed around major constructs, such as delimiting special characters or atomic strings.

NOTE:

This specification for ABNF does not provide for implicit specification of linear white space.

Any grammar that wishes to permit linear white space around delimiters or string segments must specify it explicitly. It is often useful to provide for such white space in "core" rules that are then used variously among higher-level rules. The "core" rules might be formed into a lexical analyzer or simply be part of the main ruleset.

3.2. Alternatives: Rule1 / Rule2​

Elements separated by a forward slash ("/") are alternatives. Therefore,

  foo / bar

will accept or .

NOTE:

A quoted string containing alphabetic characters is a special form for specifying alternative characters and is interpreted as a non- terminal representing the set of combinatorial strings with the contained characters, in the specified order but with any mixture of upper- and lowercase.

3.3. Incremental Alternatives: Rule1 =/ Rule2​

It is sometimes convenient to specify a list of alternatives in fragments. That is, an initial rule may match one or more alternatives, with later rule definitions adding to the set of alternatives. This is particularly useful for otherwise independent specifications that derive from the same parent ruleset, such as often occurs with parameter lists. ABNF permits this incremental definition through the construct:

      oldrule     =/ additional-alternatives

So that the ruleset

      ruleset     =  alt1 / alt2

      ruleset     =/ alt3

      ruleset     =/ alt4 / alt5

is the same as specifying

      ruleset     =  alt1 / alt2 / alt3 / alt4 / alt5

3.4. Value Range Alternatives: %c##-##​

A range of alternative numeric values can be specified compactly, using a dash ("-") to indicate the range of alternative values. Hence:

      DIGIT       =  %x30-39

is equivalent to:

      DIGIT       =  "0" / "1" / "2" / "3" / "4" / "5" / "6" /
                 "7" / "8" / "9"

Concatenated numeric values and numeric value ranges cannot be specified in the same string. A numeric value may use the dotted notation for concatenation or it may use the dash notation to specify one value range. Hence, to specify one printable character between end-of-line sequences, the specification could be:

      char-line = %x0D.0A %x20-7E %x0D.0A

3.5. Sequence Group: (Rule1 Rule2)​

Elements enclosed in parentheses are treated as a single element, whose contents are strictly ordered. Thus,

  elem (foo / bar) blat

matches (elem foo blat) or (elem bar blat), and

  elem foo / bar blat

matches (elem foo) or (bar blat).

NOTE:

It is strongly advised that grouping notation be used, rather than relying on the proper reading of "bare" alternations, when alternatives consist of multiple rule names or literals.

Hence, it is recommended that the following form be used:

 (elem foo) / (bar blat)

It will avoid misinterpretation by casual readers.

The sequence group notation is also used within free text to set off an element sequence from the prose.

3.6. Variable Repetition: *Rule​

The operator "*" preceding an element indicates repetition. The full form is:

  <a>*<b>element

where and are optional decimal values, indicating at least and at most occurrences of the element.

Default values are 0 and infinity so that allows any number, including zero; 1 requires at least one; 33 allows exactly 3; and 12 allows one or two.

3.7. Specific Repetition: nRule​

A rule of the form:

  <n>element

is equivalent to

  <n>*<n>element

That is, exactly occurrences of . Thus, 2DIGIT is a 2-digit number, and 3ALPHA is a string of three alphabetic characters.

3.8. Optional Sequence: [RULE]​

Square brackets enclose an optional element sequence:

  [foo bar]

is equivalent to

  *1(foo bar).

3.9. Comment: ; Comment​

A semicolon starts a comment that continues to the end of line. This is a simple way of including useful notes in parallel with the specifications.

3.10. Operator Precedence​

The various mechanisms described above have the following precedence, from highest (binding tightest) at the top, to lowest (loosest) at the bottom:

Rule name, prose-val, Terminal value

Comment

Value range

Repetition

Grouping, Optional

Concatenation

Alternative

Use of the alternative operator, freely mixed with concatenations, can be confusing.

Again, it is recommended that the grouping operator be used to make explicit concatenation groups.