Annexe A. ABNF collecté (Collected ABNF)

Cette annexe fournit une vue consolidée de toutes les règles ABNF définies dans cette spécification.

HTTP-message   = start-line CRLF
                 *( field-line CRLF )
                 CRLF
                 [ message-body ]

HTTP-version  = HTTP-name "/" DIGIT "." DIGIT
HTTP-name     = %s"HTTP"

absolute-URI  = <absolute-URI, voir [URI], Section 4.3>
absolute-path = <absolute-path, voir [HTTP], Section 4.1>
authority     = <authority, voir [URI], Section 3.2>

chunk          = chunk-size [ chunk-ext ] CRLF
                 chunk-data CRLF
chunk-data     = 1*OCTET
chunk-ext      = *( BWS ";" BWS chunk-ext-name
                    [ BWS "=" BWS chunk-ext-val ] )
chunk-ext-name = token
chunk-ext-val  = token / quoted-string
chunk-size     = 1*HEXDIG

chunked-body   = *chunk
                 last-chunk
                 trailer-section
                 CRLF

field-line     = field-name ":" OWS field-value OWS
field-name     = <field-name, voir [HTTP], Section 5.1>
field-value    = <field-value, voir [HTTP], Section 5.5>

last-chunk     = 1*("0") [ chunk-ext ] CRLF

message-body   = *OCTET

method         = token

obs-fold       = OWS CRLF RWS
obs-text       = <obs-text, voir [HTTP], Section 5.6.4>

origin-form    = absolute-path [ "?" query ]

query          = <query, voir [URI], Section 3.4>
quoted-string  = <quoted-string, voir [HTTP], Section 5.6.4>

reason-phrase  = 1*( HTAB / SP / VCHAR / obs-text )
request-line   = method SP request-target SP HTTP-version
request-target = origin-form
               / absolute-form
               / authority-form
               / asterisk-form

start-line     = request-line / status-line
status-code    = 3DIGIT
status-line    = HTTP-version SP status-code SP [ reason-phrase ]

token          = <token, voir [HTTP], Section 5.6.2>
trailer-section = *( field-line CRLF )
transfer-coding = <transfer-coding, voir [HTTP], Section 10.1.4>

uri-host       = <host, voir [URI], Section 3.2.2>